**********************
*** 2 period panel ***
**********************

use "C:\Users\royj\Dropbox\eco5720\Data Sets- STATA\CRIME2.DTA", clear

g citid = .

forval j = 1/46 {
	replace citid = `j' if _n==2*`j' | _n==(2*`j' - 1)
}

reg crmrte unem d87

* Removing the effect of d87 from unem
reg unem d87
predict runem, res
reg crmrte runem

* Accounting for city effect by first-differencing
reg ccrmrte cunem

* If we had to first difference
g yearid = .
replace yearid = 1 if year==82
replace yearid = 2 if year==87
xtset citid yearid
reg D.(crmrte d87 unem), nocons

twoway (scatter crmrte runem, sort xtitle("Unemployment Rate Removing 1987") ytitle("Crime Rate")) || (lfit crmrte runem, sort) || (scatter ccrmrte cunem, sort) || (lfit ccrmrte cunem, sort)

***********************
*** >2 period panel ***
***********************

use "C:\Users\royj\Dropbox\eco5720\Data Sets- STATA\CRIME4.DTA", clear
xtset county year
reg lcrmrte d82 d83 d84 d85 d86 d87 lavgsen lpolpc
reg D.(lcrmrte d82 d83 d84 d85 d86 d87 lavgsen lpolpc), nocons
reg clcrmrte d83 d84 d85 d86 d87 clavgsen clpolpc
reg clcrmrte d83 d84 d85 d86 d87 clavgsen clpolpc, vce(cluster county)

use "C:\Users\royj\Dropbox\eco5720\Data Sets- STATA\JTRAIN.DTA", clear
xtset fcode year

* OLS estimator
reg lscrap d88 d89 grant grant_1

* First-differenced estimator
reg D.(lscrap d88 d89 grant grant_1)

* Fixed effects estimator
xtreg lscrap d88 d89 grant grant_1, fe

* Dummy variable regression
reg lscrap d88 d89 grant grant_1 i.fcode

* Random effects estimator
xtreg lscrap d88 d89 grant grant_1, re